メールに分類項目とコメントを付けて転送するマクロ


コメントにて以下のご要望をいただきました。


2014年12月14日に 「添付ファイルをディスクに保存し、そのファイルへのリンクをメッセージの添付ファイルと置き換えるマクロ」で対応できないメールアドレスの処理についての質問をさせてもらった sumi2g と言います。
その後追加で教えていただいたマクロでも望む結果は得られなかったのですがマニュアル操作で対応していました。今回はそのマニュアル対応の手順をマニュアル化していただけないかと思いメールさせていただきました。
マクロ化を希望する手順は下記の通りとなります。
(1) 「添付ファイルをディスクに保存し、そのファイルへのリンクをメッセージの添付ファイルと置き換えるマクロ」で対応できないメール(以下、対応不可メール、と書きます。)を自分のアドレス(特定のアドレス)に転送する。
(2) 転送メールするメールの本文の1行目に特定の文字列を入れる。(現状では「添付ファイル保存用転送メール」と入れています)
(3) 転送メールに特定の分類項目をつける。(現状では「添付ファイル保存用転送メール」という分類項目を作って選択しています)
(4) 転送メールを送信する。
(5) 対応不可メールの添付ファイルを削除する。
(6) 対応不可メールに特定の分類項目をつける。(現状では「添付転送+消去済」という分類項目を作って選択しています)
上記のステップで対応するのが僕の環境では最も自然に対応できているため是非マクロ化をお願いします。

OUTLOOKは 2013、OSは Windows 10です。
よろしくお願いします。


以下のようなマクロで実現できます。

' ここをトリプルクリックでマクロ全体を選択できます。
Public Sub ForwardWithCategoryAndComment()
    Const FORWARD_ADDRESS = "user@example.com"
    Const FORWARD_CATEGORY = "添付ファイル保存用転送メール"
    Const FORWARD_COMMENT = "添付ファイル保存用転送メール" & vbCrLf
    Const PROCESSED_CATEGORY = "添付転送+消去済"
    Dim curItem As MailItem
    Dim fwdItem As MailItem
    Dim fwdInsp As Inspector
    Dim i As Integer
    '
    Set curItem = ActiveInspector.CurrentItem
    ' 開いているメールの転送メールを作成する
    Set fwdItem = curItem.Forward
    ' 転送メールのあて先を指定する
    fwdItem.Recipients.Add (FORWARD_ADDRESS)
    ' 転送メールの本文に特定の文字列を入れる
    Set fwdInsp = fwdItem.GetInspector
    fwdInsp.Display
    fwdInsp.WordEditor.Application.Selection.TypeText FORWARD_COMMENT
    ' 転送メールに特定の分類項目をつける
    fwdItem.Categories = FORWARD_CATEGORY
    ' 転送メールを送信する
    fwdItem.Send
    ' 対応不可メールの添付ファイルを削除する
    For i = curItem.Attachments.Count To 1 Step -1
        curItem.Attachments.Remove i
    Next
    ' 対応不可メールに特定の分類項目をつける
    curItem.Categories = PROCESSED_CATEGORY
    curItem.Save
End Sub

マクロの登録方法やメニューへの追加について

広告

メールに分類項目とコメントを付けて転送するマクロ」への2件のフィードバック

  1. sumi2gです。遅くなりましたが動作の確認ができたのでコメントさせてもらいます。
    まず、機能としては僕が希望していた内容が完全に実現されていました。本当にありがとうございました!!!
    一つだけ質問させてください。
    以前から使わせて頂いている「AttachmentsSaveHyperLinkAndDelete」ではメールを開かなくともリストの中で選択してマクロを走らせると機能するのですが、今回の「ForwardWithCategoryAndComment」ではリスト表示の中で対象メールを選択した状態ではマクロが動作しません。リストからダブルクリックしてメールを開いた状態にしてからマクロを走らせると問題なく動作するので十分使わせてもらっていますが、疑問が残っています・・・ また時間がおありの時などに教えてもらえると嬉しいです。
    でも、本当にありがとうございました!!!

コメントを残す

以下に詳細を記入するか、アイコンをクリックしてログインしてください。

WordPress.com ロゴ

WordPress.com アカウントを使ってコメントしています。 ログアウト / 変更 )

Twitter 画像

Twitter アカウントを使ってコメントしています。 ログアウト / 変更 )

Facebook の写真

Facebook アカウントを使ってコメントしています。 ログアウト / 変更 )

Google+ フォト

Google+ アカウントを使ってコメントしています。 ログアウト / 変更 )

%s と連携中