指定されたドメイン以外への送信を防ぐマクロ


コメントにて以下のご要望をいただきました。


Outlook2013を使用しています。

メールの誤送信を防ぐ為と内部セキュリティー強化に取引先数社のドメイン以外に送信できないように出来ないでしょうか。



Outlook で送信時に宛先をチェックするという場合、Application の ItemSend イベントを使用します。
たとえば、以下のようなマクロで実現できます。
Array で送信可能なドメインを指定してください。

' ここをトリプルクリックでマクロ全体を選択できます。
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim arrAllowedDomains
    ' 送信可能なドメイン名を指定
    arrAllowedDomains = Array("example.com", "contoso.com")
    Dim oRec As Recipient
    Dim i As Integer
    Dim strErr As String
    Dim bAllow As Boolean
    For Each oRec In Item.Recipients
        bAllow = False
        For i = 0 To UBound(arrAllowedDomains)
            If oRec.Address Like "*@" & arrAllowedDomains(i) Then
                bAllow = True
                Exit For
            End If
        Next
        ' 送信可能なドメインではない受信者が存在したら送信キャンセル
        If Not bAllow Then
            Cancel = True
            strErr = strErr & oRec.Address & ";"
        End If
    Next
    ' 送信がキャンセルされた場合にはエラー表示
    If Cancel Then
        MsgBox "以下のアドレスへの送信は許可されていません。" & vbCrLf & strErr
    End If
End Sub

マクロの登録方法やメニューへの追加について

広告

コメントを残す

以下に詳細を記入するか、アイコンをクリックしてログインしてください。

WordPress.com ロゴ

WordPress.com アカウントを使ってコメントしています。 ログアウト / 変更 )

Twitter 画像

Twitter アカウントを使ってコメントしています。 ログアウト / 変更 )

Facebook の写真

Facebook アカウントを使ってコメントしています。 ログアウト / 変更 )

Google+ フォト

Google+ アカウントを使ってコメントしています。 ログアウト / 変更 )

%s と連携中