予定表の選択した時間に決まった宛先、分類項目、公開方法の会議を作成するマクロ


コメントにて以下のご要望をいただきました。


いつもお世話になっております。
予定表アイテムを作成する時に、予め下記の設定をしておくことは可能でしょうか?

●送信先(いつも同じ宛先を1ついれたいです)
●分類項目
●外出設定(公開方法の部分です)
(●開始時刻~終了時刻までの時間を1時間に設定(できれば))

5月12日15時にそのアイテムを作成したいと思ったら、
5月12日15時の部分を選択し、そのマクロを実行すると自動的にアイテムが作成される、
という運用ができると大変有難いです。

移動時間、外出、来客によって、分類や公開方法を決めているのですが
これをマクロ化できると毎日の作業が楽になるな、と思っております。

ご検討どうぞよろしくお願い致します。



Outlook 2010 以降では、CalendarView.SelectedStartTime プロパティで予定表の選択された範囲の開始時刻を取得できます。
CreateItem で予定アイテムを作成し、SelectedStartTime を開始時刻とした会議出席依頼を作れば、ご要望の動作は可能です。
下記のサンプルでは、共通処理部分を CreateApptInt というサブルーチンで実現しているため、このサブを以下のような引数で呼び出すマクロを定義してください。
引数1 = 宛先のアドレス
引数2 = 分類項目
引数3 = 公開方法
引数4 = 予定の長さ (単位は時。分は小数点で表せる)

' ここをトリプルクリックでマクロ全体を選択できます。
' 予定ありで 1 時間
Public Sub CreateAppointment1()
    CreateApptInt "test1@example.com", "Project1", olBusy, 1
End Sub
' 外出中で 2 時間
Public Sub CreateAppointment2()
    CreateApptInt "test2@example.com", "Project2", olOutOfOffice, 2
End Sub
' 仮の予定で 30 分
Public Sub CreateAppointment3()
    CreateApptInt "test3@example.com", "Project3", olTentative, 0.5
End Sub
' 予定アイテムを作成するサブ
Public Sub CreateApptInt(strAttendee As String, strCategory As String, iBusy As OlBusyStatus, dblHour As Double)
    Dim apptItem As AppointmentItem
    Set apptItem = CreateItem(olAppointmentItem)
    apptItem.RequiredAttendees = strAttendee
    apptItem.Categories = strCategory
    apptItem.BusyStatus = iBusy
    apptItem.Start = ActiveExplorer.CurrentView.SelectedStartTime
    apptItem.End = DateAdd("n", dblHour * 60, apptItem.Start)
    apptItem.MeetingStatus = olMeeting
    apptItem.Display
End Sub

マクロの登録方法やメニューへの追加について

予定表の選択した時間に決まった宛先、分類項目、公開方法の会議を作成するマクロ」への5件のフィードバック

  1. 早速にありがとうございました!!
    strSubjectを加えて、OUTLOOK内にショートカットのボタンを作りました。細かな作業ですが、時短になります。
    今後ともよろしくお願い致します。

  2. 度々失礼します。
    時間を30分にしたいと思い、「0.5」をいれると、「17:00~17:00」のように「0時間」になってしまうのですが
    こちら解決方法ご教示頂けますでしょうか?

  3. お世話になっております。
    こちらのマクロ、大変活用させて頂いております!

    1点お伺いしたいのですが、このマクロを使ってスケジュールを送信する際に、送信元を自分ではなく、代理権限を持っているアカウントから送信する、という機能を付け加えることは可能でしょうか?

コメントを残す

以下に詳細を記入するか、アイコンをクリックしてログインしてください。

WordPress.com ロゴ

WordPress.com アカウントを使ってコメントしています。 ログアウト / 変更 )

Twitter 画像

Twitter アカウントを使ってコメントしています。 ログアウト / 変更 )

Facebook の写真

Facebook アカウントを使ってコメントしています。 ログアウト / 変更 )

Google+ フォト

Google+ アカウントを使ってコメントしています。 ログアウト / 変更 )

%s と連携中