特定のフォルダーのメッセージに返信する際に自動的に送信アカウントを変更するマクロ


特定の受信者に送信する際に自動的に送信アカウントを変更するマクロのコメントにて以下のようなご要望をいただきました。


このマクロを、
・特定のフォルダに分類されたメールに返信する際に、送信アカウントを変更(確認)する
ように変更できませんでしょうか?
よろしくお願いします。


送信時に実行されるマクロでは元のメッセージがどのフォルダに格納されていたかを判断することはできませんが、マクロを使って返信した場合に元のメッセージのフォルダーに従って送信アカウントを設定するというようなものなら可能です。サンプルは以下の通りです。

' ここをトリプルクリックでマクロ全体を選択できます。
Public Sub ReplyAllByFolder()
    Const SEND_ACCOUNT = "test@example.com" ' 返信に使用するアカウント
    Const FOLDER_NAME = "TEST" ' 上記のアカウントを使って返信するフォルダー
    Dim objOrg As MailItem
    Dim objReply As MailItem
    '
    If Not ActiveInspector Is Nothing Then
        Set objOrg = ActiveInspector.CurrentItem
    ElseIf ActiveExplorer.Selection.Count = 1 Then
        Set objOrg = ActiveExplorer.Selection(1)
    ElseIf ActiveExplorer.Selection.Count > 1 Then
        MsgBox "メッセージは 1 通だけ選択してください。"
        Exit Sub
    Else
        MsgBox "メッセージを選択するか、開いてから実行してください。"
        Exit Sub
    End If
    '
    Set objReply = objOrg.ReplyAll
    objReply.Display
    If objOrg.Parent.Name = FOLDER_NAME Then
        ' 指定されたフォルダーの返信メッセージの送信アカウントを変更
        Dim objAccount As Account
        Dim objInspector As Inspector
        Set objAccount = Session.Accounts(SEND_ACCOUNT)
        Set objInspector = objReply.GetInspector
        Set objInspector.CurrentItem.SendUsingAccount = objAccount
    End If
End Sub

マクロの登録方法やメニューへの追加について

広告

特定のフォルダーのメッセージに返信する際に自動的に送信アカウントを変更するマクロ」への1件のフィードバック

  1. サンプルマクロありがとうございます。お礼が遅くなってしまい申し訳ありませんでした。

コメントを残す

以下に詳細を記入するか、アイコンをクリックしてログインしてください。

WordPress.com ロゴ

WordPress.com アカウントを使ってコメントしています。 ログアウト / 変更 )

Twitter 画像

Twitter アカウントを使ってコメントしています。 ログアウト / 変更 )

Facebook の写真

Facebook アカウントを使ってコメントしています。 ログアウト / 変更 )

Google+ フォト

Google+ アカウントを使ってコメントしています。 ログアウト / 変更 )

%s と連携中