投票ボタンの返信状況を Excel にエクスポートするマクロ


Outlook には投票ボタンという機能があり、いくつかの選択肢から一つを選んで返信するという処理を自動化することができます。そして、返信状況は送信済みアイテムの [確認] タブで確認が可能です。

この情報は先週の記事にあった会議出席依頼の返信状況とは異なり、すべて選択してコピーし Excel に貼り付けることで、Excel にエクスポートすることが可能です。しかし、エクスポートされたデータは一つのセルに「返信文字列: 返信日付」というように格納されてしまうため、その後の加工がしづらいという問題があります。

そこで、返信状況と日付を別々にエクスポートするマクロを作りました。

返信状況をエクスポートしたい予定を開いてこのマクロを実行すると、Excel で新規のワークブックが作成され、そこに返信状況がエクスポートされます。

' ここをトリプルクリックでマクロ全体を選択できます。
Public Sub ExportTrackingStatusToExcel()
    Dim objMail As MailItem
    Dim objRecp As Recipient
    Dim appExcel
    Dim objWorkbook
    Dim objSheet
    Dim iRow
    Dim arrStatus
    arrStatus = Array("なし", "配信済み", "配信不能", "未開封", "取り消し失敗", "取り消し成功", "開封済み")
'
    Set appExcel = CreateObject("Excel.Application")
    Set objWorkbook = appExcel.Workbooks.Add
    Set objSheet = objWorkbook.Sheets(1)
    objSheet.cells(1, 1) = "名前"
    objSheet.cells(1, 2) = "状況"
    objSheet.cells(1, 3) = "確認日時"
    Set objMail = ActiveInspector.CurrentItem
    iRow = 2
    For Each objRecp In objMail.Recipients
        With objRecp
            objSheet.cells(iRow, 1) = .Name
            If .TrackingStatus = olTrackingReplied Then
                objSheet.cells(iRow, 2) = .AutoResponse
            Else
                objSheet.cells(iRow, 2) = arrStatus(.TrackingStatus)
            End If
            If .TrackingStatus <> olTrackingNone Then
                objSheet.cells(iRow, 3) = .TrackingStatusTime
            End If
        End With
        iRow = iRow + 1
    Next
'
    appExcel.Visible = True
End Sub

マクロの登録方法やメニューへの追加について

投票ボタンの返信状況を Excel にエクスポートするマクロ」への2件のフィードバック

  1. はじめまして。OUTLOOKのマクロコード、大変助かります。
    投票ボタンの集計は便利なので、ときどき使うのですが、集計がしにくくって困っていました。

    もしわかるようでしたら、教えてください。
    差出人をBCCにした場合は、どんなコードになりますでしょうか。

    大変お手数ですが、よろしくお願いいたします。

コメントを残す

以下に詳細を記入するか、アイコンをクリックしてログインしてください。

WordPress.com ロゴ

WordPress.com アカウントを使ってコメントしています。 ログアウト / 変更 )

Twitter 画像

Twitter アカウントを使ってコメントしています。 ログアウト / 変更 )

Facebook の写真

Facebook アカウントを使ってコメントしています。 ログアウト / 変更 )

Google+ フォト

Google+ アカウントを使ってコメントしています。 ログアウト / 変更 )

%s と連携中