会議出席依頼の応答を Excel にエクスポートするマクロ


Outlook で会議出席依頼を送信し、それに対して出席者が返信をすると、元となった予定の [履歴管理] ページに出席者ごとの返信状況が表示されます。しかし、この情報を Excel などで利用しようと全体を選択してコピーしても、残念ながら返信状況がコピーされません。

そこで、出席者ごとの返信状況を Excel にエクスポートするマクロを作りました。

返信状況をエクスポートしたい予定を開いてこのマクロを実行すると、Excel で新規のワークブックが作成され、そこに返信状況がエクスポートされます。

' ここをトリプルクリックでマクロ全体を選択できます。
Public Sub ExportMeetingResponsesToExcel()
    Dim objAppt As AppointmentItem
    Dim objRecp As Recipient
    Dim appExcel
    Dim objWorkbook
    Dim objSheet
    Dim iRow
    Dim arrType
    arrType = Array("開催者", "出席者", "任意出席者", "リソース")
    Dim arrStatus
    arrStatus = Array("なし", "開催者", "仮承諾", "承諾", "辞退", "返答なし")
'
    Set appExcel = CreateObject("Excel.Application")
    Set objWorkbook = appExcel.Workbooks.Add
    Set objSheet = objWorkbook.Sheets(1)
    objSheet.cells(1, 1) = "名前"
    objSheet.cells(1, 2) = "出席者の構成"
    objSheet.cells(1, 3) = "返信状況"
    objSheet.cells(1, 4) = "返信日時"
    Set objAppt = ActiveInspector.CurrentItem
    iRow = 2
    For Each objRecp In objAppt.Recipients
        With objRecp
            objSheet.cells(iRow, 1) = .Name
            If .Name = ActiveInspector.CurrentItem.Organizer Then
                objSheet.cells(iRow, 2) = "開催者"
            Else
                objSheet.cells(iRow, 2) = arrType(.Type)
            End If
            objSheet.cells(iRow, 3) = arrStatus(.MeetingResponseStatus)
            If .MeetingResponseStatus <> olResponseNone And .MeetingResponseStatus <> olResponseNotResponded Then
                objSheet.cells(iRow, 4) = .TrackingStatusTime
            End If
        End With
        iRow = iRow + 1
    Next
    appExcel.Visible = True
End Sub

マクロの登録方法やメニューへの追加について

会議出席依頼の応答を Excel にエクスポートするマクロ」への6件のフィードバック

  1. 上記の会議出欠情報をエクスポートするのはすごく便利ですが、メールアドレスも同時にエクスポートできるとさらに便利になりますが、可能ですか?

  2. […] 会議出席依頼の応答を Excel にエクスポートするマクロ ver 2 カテゴリー: Outlook 2007 マクロ,Outlook 2010 マクロ — outlooklab @ 12:00 PM 以前、会議出席依頼の応答を Excel にエクスポートするマクロを作成したのですが、そのマクロのコメントにメールアドレスもエクスポートするとさらに便利になるとのご意見をいただきました。 […]

  3. 素晴らしく便利になりました。 ありがとうございます。 またお礼を申し上げるのが遅くなりましたこと深くお詫びいたします。

コメントを残す

以下に詳細を記入するか、アイコンをクリックしてログインしてください。

WordPress.com ロゴ

WordPress.com アカウントを使ってコメントしています。 ログアウト / 変更 )

Twitter 画像

Twitter アカウントを使ってコメントしています。 ログアウト / 変更 )

Facebook の写真

Facebook アカウントを使ってコメントしています。 ログアウト / 変更 )

Google+ フォト

Google+ アカウントを使ってコメントしています。 ログアウト / 変更 )

%s と連携中